Распознавание DataMatrix со снимка в 1С: облачный API или утилита на своём сервере
В 1С коды маркировки обычно приходят со сканера штрихкодов: он сам читает DataMatrix и передаёт строку в базу. Но бывает, что сканера нет, а есть снимок: фото коробки от кладовщика, кадр камеры над столом упаковки, скан документа, папка с фотографиями от поставщика. Тогда код нужно распознать со снимка. Ниже — два способа сделать это из 1С без внешних компонент: через облачный API и через утилиту на своём компьютере или сервере.
Какой способ выбрать
| Облачный API | Утилита unir на своей машине | |
|---|---|---|
| Что ставить | ничего, нужен ключ API | архив с утилитой на компьютер или сервер 1С |
| Интернет | нужен | не нужен |
| Снимок | уходит на наш сервер | остаётся у вас |
| Цена | 300 запросов в месяц бесплатно, дальше — тариф API | лицензия библиотеки, первый месяц бесплатно |
| Подходит | несколько десятков или сотен снимков в день | поток снимков, закрытая сеть, много кодов на снимке |
Оба способа читают DataMatrix, QR, GS1-128 (SSCC), EAN/UPC и Code 128 и возвращают код «Честного знака» вместе с разделителем GS — его нельзя терять, иначе код не пройдёт проверку. Почему — в статье о разделителе GS.
Способ 1. Облачный API
Ключ API выдаётся в личном кабинете, бесплатный тариф — 300 запросов в месяц и 30 в сутки. Снимок — JPEG или PNG до 8 МБ и до 16 Мп. Функцию можно вызывать и на клиенте, и на сервере 1С:
// Возвращает массив строк — тексты кодов со снимка.
// Разделитель GS1 в тексте — настоящий символ Символ(29).
Функция РаспознатьКодыAPI(ПутьКСнимку, КлючAPI) Экспорт
Соединение = Новый HTTPСоединение("api.libscanner.com", 443, , , , 30,
Новый ЗащищенноеСоединениеOpenSSL);
Запрос = Новый HTTPЗапрос("/v1/decode?mode=multi");
Запрос.Заголовки.Вставить("Authorization", "Bearer " + КлючAPI);
Запрос.Заголовки.Вставить("Content-Type", "application/octet-stream");
Запрос.УстановитьТелоИзДвоичныхДанных(Новый ДвоичныеДанные(ПутьКСнимку));
Ответ = Соединение.ОтправитьДляОбработки(Запрос);
ТекстОтвета = Ответ.ПолучитьТелоКакСтроку("UTF-8");
Если Ответ.КодСостояния <> 200 Тогда
ВызватьИсключение "API распознавания: " + Ответ.КодСостояния + " " + ТекстОтвета;
КонецЕсли;
Чтение = Новый ЧтениеJSON;
Чтение.УстановитьСтроку(ТекстОтвета);
Результат = ПрочитатьJSON(Чтение, Истина); // Истина — в Соответствие
Чтение.Закрыть();
Коды = Новый Массив;
Для Каждого Код Из Результат["codes"] Цикл
Коды.Добавить(Код["text"]);
КонецЦикла;
Возврат Коды;
КонецФункцииОтвет читается в Соответствие, а не в структуру: с параметром gs1=true в ответе есть разбор полей с ключами вида "01", а такие ключи структура не принимает. Поле status равно not_found, если кода на снимке нет, и not_decoded, если символ найден, но не читается (смазан, обрезан). Остальные поля, коды ошибок и лимиты — в документации API.
Ключ API — секрет учётной записи: храните его в константе или в защищённом хранилище, а не в тексте модуля.
Способ 2. Утилита на своём компьютере или сервере
Утилита unir лежит в архиве для Windows и Linux (раздел «Загрузки» личного кабинета; для Python — пакет libscanner-unir). Первый месяц она работает без лицензии и без интернета. 1С запускает её как внешнюю программу и читает результат из файла:
// Windows. ПутьУтилиты — например "C:\libscanner\bin\unir.exe".
// Возвращает массив строк — тексты кодов со снимка.
Функция РаспознатьКодыЛокально(ПутьКСнимку, ПутьУтилиты) Экспорт
Каталог = ПолучитьИмяВременногоФайла("unir");
СоздатьКаталог(Каталог);
Снимок = Новый Файл(ПутьКСнимку);
КопироватьФайл(ПутьКСнимку, Каталог + "\" + Снимок.Имя);
ФайлРезультата = ПолучитьИмяВременногоФайла("tsv");
// --folder — все снимки каталога, --codes 0 — все коды на снимке.
Команда = "cmd /c """"" + ПутьУтилиты + """ --folder """ + Каталог
+ """ --codes 0 > """ + ФайлРезультата + """""";
КодВозврата = 0;
ЗапуститьПриложение(Команда, , Истина, КодВозврата);
Текст = Новый ТекстовыйДокумент;
Текст.Прочитать(ФайлРезультата, КодировкаТекста.UTF8);
Коды = Новый Массив;
Для Н = 1 По Текст.КоличествоСтрок() Цикл
// путь <TAB> код возврата <TAB> мс <TAB> текст <TAB> символика
Поля = СтрРазделить(Текст.ПолучитьСтроку(Н), Символы.Таб, Истина);
Если Поля.Количество() >= 5 И Поля[1] = "0" И Поля[3] <> "" Тогда
Коды.Добавить(СтрЗаменить(Поля[3], "<GS>", Символ(29)));
КонецЕсли;
КонецЦикла;
УдалитьФайлы(Каталог);
УдалитьФайлы(ФайлРезультата);
Возврат Коды;
КонецФункцииЧто важно:
- Разделитель GS. В текстовом выводе утилиты GS записан как
<GS>, функция заменяет его настоящим символом. В серийном номере кода маркировки сочетание символов<GS>теоретически возможно; если нужна гарантия точных байтов кода, берите API (полеbytes_base64) или библиотеку для Python и C++. - Код возврата. 0 — код прочитан, 3 — нет лицензии (пробный месяц кончился); полный список — в документации утилиты.
- Сервер 1С на Linux. То же самое, но утилита —
bin/unir, а команда запускается черезsh -cвместоcmd /c. - Много снимков. Не запускайте утилиту на каждый снимок по отдельности: положите все снимки в один каталог и разберите их одним запуском — так быстрее. Для постоянного потока у утилиты есть режим службы
--serve.
Что дальше со строкой кода
Строка кода «Честного знака» — это GTIN, серийный номер и код проверки, разделённые GS. Разобрать её на поля можно по идентификаторам применения — они описаны в статье об идентификаторах применения. Статус кода (в обороте, выбыл, чей) проверяется в системе «Честный знак» — как это сделать, рассказано в статье о проверке кода.
Подключим под вашу конфигурацию
Если нужно не пример, а готовое решение — обработка или расширение для вашей конфигурации, чтение с камеры над столом упаковки, агрегация коробок по снимку, работа в закрытой сети, — сделаем под заказ. Начинаем с бесплатной оценки на ваших снимках: присылаете 50–200 кадров, мы говорим, сколько кодов читается и что можно улучшить. Цена и срок — по смете после оценки. Подробнее — на странице доработки под заказ или сразу напишите о задаче.
1С:Предприятие — товарный знак ООО «1С»; наш продукт не связан с ООО «1С» и не сертифицирован им.
«Честный знак» — товарный знак ООО «Оператор-ЦРПТ», «GS1» — GS1 AISBL; продукт не связан с их владельцами и ими не сертифицирован.